En la Lotería de Navidad siempre nos aparece la misma pregunta, si tengo un número o una participación y sale el gordo u otro premio, ¿cuanto me ha tocado?

Con esta pequeña hoja de Excel podremos introducir el número con el que jugamos, el importe del décimo o participación y los 5 primeros premios y nos devolverá los Euros que hemos ganado según lo jugado.

Veamos como hemos realizado esta hoja.

Pulsa aquí para bajarte el archivo (LoteriaNacional.xls)

A continuación explicaremos celda a celda su función y la formula que contiene:

[C4]: Reservada para introducir el número con el que jugamos.
[C5]: Euros jugados con el número introducido en la celda C4.

Celdas [C8], [C9], [C10], [C11] y [C12], reservadas para el primer, segundo, tercer, cuarto y quinto premio respectivamente.

En la celda [D8] pondremos la formula que nos mirará si el primer premio [C8] coincide con el número que jugamos [C4], si es así, estará premiado con 10.000 € por cada euro jugado. La formula final quedará de la siguiente forma =SI($C$4=C8;$C$5*10000;0)

En la celda [D9], realizaremos la misma comprobación pero con el segundo premio [C9], si está premiado se calculará sobre 4.800 € por euro jugado. =SI($C$4=C9;$C$5*4800;0)

Observa que hemos introducido $ para así poder copiar la formula hasta la celda [C12], de tal forma que automáticamente se realiza la comprobación con cada uno de los premios [C10], [C11] y [C12]. El tercer premio se premia con 2.400 € por euro jugado, el cuarto premio son 1.000 € por euro jugado y el quinto premio son 240 € por euro jugado.

Las formulas quedarán de la siguiente forma:
[C10] =SI($C$4=C10;$C$5*2400;0)
[C11] =SI($C$4=C11;$C$5*1000;0)
[C12] =SI($C$4=C12;$C$5*240;0)

De la [E8] a la [E10] miramos si nuestro número jugado [C4] es el superior C4+1 o inferior C4-1 a cada uno de los premios. En este caso tenemos que utilizar un O, ya que puede ser que sea superior o inferior al premio, si es así cobraremos 100 € por euro jugado en el caso del primer premio, 60 € por euro jugado en el caso del segundo premio y 48 € por euro jugado en caso del tercer premio. Las formulas serán las siguientes:
[E8] =SI(O($C$4-1=C8;$C$4+1=C8);$C$5*100;0)
[E9] =SI(O($C$4-1=C9;$C$4+1=C9);$C$5*60;0)
[E10] =SI(O($C$4-1=C10;$C$4+1=C10);$C$5*48;0)

De la [F8] a la [F10] miraremos si las dos últimas cifras del Primer, Segundo y Tercer premio coinciden con el número que nosotros jugamos. Para ello utilizaremos la función DERECHA, en la que como primer argumento indicaremos la celda donde se encuentra algunos de los números para mirar las dos últimas cifras, mirando por la derecha y como segundo argumento el número de dígitos que deseamos obtener, en este caso 2. Las dos últimas cifras del Primer número tienen un premio de 6 € por euro jugado, las dos últimas cifras del segundo y tercer premio tienen un premio de 5 € por euro jugado.

En estas tres formulas hemos realizado previamente una comprobación para saber si el número que estamos jugando ya ha sido premiado con el premio completo, si es así, pondremos como resultado 0 €.
[F8] =SI($C$4<>C8;SI(DERECHA($C$4;2)=DERECHA(C8;2);$C$5*6;0);0)
[F9] =SI($C$4<>C9;SI(DERECHA($C$4;2)=DERECHA(C9;2);$C$5*5;0);0)
[F10] =SI($C$4<>C10;SI(DERECHA($C$4;2)=DERECHA(C10;2);$C$5*5;0);0)

Por último nos queda calcular el reintegro. Solamente se consigue en el momento que coincide la última cifra del Primer premio con la última cifra del número que jugamos. En esta celda realizaremos una comprobación para ver si el número ha sido premiado con el Primer premio o por lo contrario con las dos últimas cifras de este Primer premio, si fuera así... no está premiado con la devolución.
[G8] =SI(Y(D8=0;F8=0);SI(DERECHA(C8;1)=DERECHA(C4;1);C5;0);0)

En la celda [G14] hemos puesto la suma total de lo ganado con este sorteo.

Ahora sólo queda tener suerte y esperar que la comprobación de los números jugados sea positiva.

Desde aquí... suerte a todos.